3 # Password history via Heimdal external strength checking.
5 # This script is meant to be called via the Heimdal external password strength
6 # checking interface and maintains per-user password history. Password
7 # history is stored as Crypt::PBKDF2 hashes with random salt for each
10 # Written by Russ Allbery <eagle@eyrie.org>
11 # Copyright 2013, 2014
12 # The Board of Trustees of the Leland Stanford Junior University
14 ##############################################################################
15 # Declarations and configuration
16 ##############################################################################
25 use Fcntl qw(O_CREAT O_RDWR);
26 use File::Basename qw(basename);
27 use Getopt::Long::Descriptive qw(describe_options);
29 use JSON qw(encode_json decode_json);
30 use POSIX qw(setgid setuid);
32 use Sys::Syslog qw(openlog syslog LOG_AUTH LOG_INFO LOG_WARNING);
34 # The most convenient interface to Berkeley DB files is ties.
35 ## no critic (Miscellanea::ProhibitTies)
37 # The number of PBKDF2 iterations to use when hashing passwords. This number
38 # should be chosen so as to force the hash operation to take approximately 0.1
39 # seconds on current hardware.
40 Readonly my $HASH_ITERATIONS => 14592;
42 # Path to the history database. Currently, this must be a Berkeley DB file in
43 # the old DB_HASH format. Keys will be principal names, and values will be a
44 # JSON array of hashes. Each hash will have two keys: timestamp, which holds
45 # the seconds since UNIX epoch at which the history entry was stored, and
46 # hash, which holds the Crypt::PBKDF2 LDAP-style password hash.
47 Readonly my $HISTORY_PATH => '/var/lib/heimdal-history/history.db';
49 # User and group used to do all password history lookups and writes, assuming
50 # that this program is invoked as root and can therefore change UID and GID.
51 Readonly my $HISTORY_USER => '_history';
52 Readonly my $HISTORY_GROUP => '_history';
54 # Path to the Berkeley DB file (DB_HASH format) that stores statistics on
55 # password length of accepted passwords. Each successful password validation
56 # will increase the counter for that length. This is read and written with
57 # $HISTORY_USER and $HISTORY_GROUP.
58 Readonly my $LENGTH_STATS_PATH => '/var/lib/heimdal-history/lengths.db';
60 # The message to return to the user if we reject the password because it was
61 # found in the user's history.
62 Readonly my $REJECT_MESSAGE => 'password was previously used';
64 # The path to the external strength checking program to run. This is done
65 # first before checking history, and if it fails, that failure is returned as
66 # the failure for this program.
67 Readonly my $STRENGTH_PROGRAM => '/usr/bin/heimdal-strength';
69 # User and group used to do password strength checking. Generally, this
70 # doesn't require any privileges since the strength dictionary is
72 Readonly my $STRENGTH_USER => 'nobody';
73 Readonly my $STRENGTH_GROUP => 'nogroup';
75 # Global boolean variable saying whether to log with syslog. This is set
76 # based on the presence of the -q (--quiet) command-line option.
79 ##############################################################################
81 ##############################################################################
83 # Change real and effective UID and GID to those for the given user and group.
84 # Does nothing if not running as root.
86 # $user - User to change the UID to
87 # $group - Group to change the GID to (and clear all supplemental groups)
90 # Throws: Text exception on any failure
92 my ($user, $group) = @_;
94 # If running as root, drop privileges. Fail if we can't get the UID and
95 # GID corresponding to our users.
96 if ($> == 0 || $< == 0) {
97 my $uid = getpwnam($user)
98 or die "$0: cannot get UID for $user\n";
99 my $gid = getgrnam($group)
100 or die "$0: cannot get GID for $group\n";
101 setgid($gid) or die "$0: cannot setgid to $gid: $!\n";
102 setuid($uid) or die "$0: cannot setuid to $uid: $!\n";
103 if ($> == 0 || $< == 0) {
104 die "$0: failed to drop permissions\n";
110 ##############################################################################
112 ##############################################################################
114 # Given a list of keys and values for a log message as a hash reference,
115 # return in encoded format following our logging protocol. The log format is
116 # a set of <key>=<value> parameters separated by a space. Values containing
117 # whitespace are quoted with double quotes, with any internal double quotes
120 # Here also is defined a custom sort order for the encoded key/value pairs to
121 # keep them in a reasonable order for a human to read.
123 # $params_ref - Reference to a hash of key/value pairs
125 # Returns: The encoded format as a string
126 sub encode_log_message {
127 my ($params_ref) = @_;
129 # Define the custom sort order for keys.
132 = map { $_ => $order++ } qw(action principal error result reason);
134 # Build the message from the parameters.
136 for my $key (sort { $order{$a} <=> $order{$b} } keys %{$params_ref}) {
137 my $value = $params_ref->{$key};
138 $value =~ s{ \" }{\"\"}xmsg;
139 if ($value =~ m{ [ \"] }xms) {
140 $value = qq{"$value"};
142 $message .= qq{$key=$value };
148 # Log a non-fatal error encountered while trying to check or store password
149 # history. This is used for errors where the password is accepted, but we ran
150 # into some anomalous event such as corrupted history data that should be
151 # drawn to the attention of an administrator. The log format is a set of
152 # <key>=<value> parameters, with the following keys:
154 # - action: the action performed (currently always "check")
155 # - principal: the principal to check a password for
156 # - error: an error message explaining the anomalous situation
158 # Values containing whitespace are quoted with double quotes, with any
159 # internal double quotes doubled. No logging will be done if $SYSLOG is
162 # $principal - Principal for which we checked a password
163 # $error - The error message
167 my ($principal, $error) = @_;
171 my $message = encode_log_message(
173 principal => $principal,
176 syslog(LOG_WARNING, '%s', $message);
180 # Log the disposition of a particular password strength checking request. All
181 # log messages are logged through syslog at class info. The log format is a
182 # set of <key>=<value> parameters, with the following keys:
184 # - action: the action performed (currently always "check")
185 # - principal: the principal to check a password for
186 # - result: either "accepted" or "rejected"
187 # - reason: the reason for a rejection
189 # Values containing whitespace are quoted with double quotes, with any
190 # internal double quotes doubled. No logging will be done if $SYSLOG is
193 # $principal - Principal for which we checked a password
194 # $result - "accepted" or "rejected" per above
195 # $reason - On rejection, the reason
199 my ($principal, $result, $reason) = @_;
204 # Create the message.
207 principal => $principal,
210 if ($result eq 'rejected' && defined($reason)) {
211 $message{reason} = $reason;
213 my $message = encode_log_message(\%message);
216 syslog(LOG_INFO, '%s', $message);
220 ##############################################################################
222 ##############################################################################
224 # Given a password, return the hash for that password. Hashing is done with
225 # PBKDF2 using SHA-2 as the underlying hash function. As of version 0.133330,
228 # $password - Password to hash
229 # $iterations - Optional iteration count, defaulting to $HASH_ITERATIONS
231 # Returns: Hash encoded in the LDAP-compatible Crypt::PBKDF2 format
233 my ($password, $iterations) = @_;
234 $iterations //= $HASH_ITERATIONS;
235 my $hasher = Crypt::PBKDF2->new(
236 hash_class => 'HMACSHA2',
237 iterations => $iterations,
239 return $hasher->generate($password);
242 # Given a password and the password history for the user as a reference to a
243 # array, check whether that password is found in the history. The history
244 # array is expected to contain anonymous hashes. The only key of interest is
245 # the "hash" key, whose value is expected to be a hash in the LDAP-compatible
246 # Crypt::PBKDF2 format.
248 # Invalid history entries are ignored for the purposes of this check and
249 # treated as if the entry did not exist.
251 # $principal - Principal to check (solely for logging purposes)
252 # $password - Password to check
253 # $history_ref - Reference to array of anonymous hashes with "hash" keys
255 # Returns: True if the password matches one of the history hashes, false
258 my ($principal, $password, $history_ref) = @_;
259 my $hasher = Crypt::PBKDF2->new(hash_class => 'HMACSHA2');
261 # Walk the history looking at each hash key.
262 for my $entry (@{$history_ref}) {
263 my $hash = $entry->{hash};
264 next if !defined($hash);
266 # validate throws an exception if the hash is in an invalid format.
267 # Treat that case the same as a miss, but log it.
268 if (eval { $hasher->validate($hash, $password) }) {
271 log_error($principal, "hash validate failed: $@");
279 ##############################################################################
281 ##############################################################################
283 # Perform a binary search for a number of hash iterations that makes password
284 # hashing take the given target time on the current system.
288 # * The system load is low enough that this benchmark result is meaningful
289 # and not heavily influenced by other programs running on the system. The
290 # binary search may be unstable if the system load is too variable.
292 # * The static "password" string used for benchmarking will exhibit similar
293 # performance to the statistically average password.
295 # Information about the iteration search process is printed to standard output
296 # while the search runs.
298 # $target - The elapsed time, in real seconds, we're aiming for
299 # $delta - The permissible delta around the target time
301 # Returns: The number of hash iterations with that performance characteristic
302 # Throws: Text exception on failure to write to standard output
303 sub find_iteration_count {
304 my ($target, $delta) = @_;
308 # A static password to use for benchmarking.
309 my $password = 'this is a benchmark';
311 # Start at the current configured iteration count. If this doesn't take
312 # long enough, it becomes the new low mark and we try double that
313 # iteration count. Otherwise, do binary search.
315 # We time twenty iterations each time, chosen because it avoids the
316 # warnings from Benchmark about too few iterations for a reliable count.
318 my $iterations = $HASH_ITERATIONS;
320 my $hash = sub { password_hash($password, $iterations) };
321 my $times = Benchmark::timethis(20, $hash, q{}, 'none');
323 # Extract the CPU time from the formatted time string. This will be
324 # the total time for all of the iterations, so divide by the iteration
325 # count to recover the time per iteration.
326 my $report = Benchmark::timestr($times);
327 my ($time) = ($report =~ m{ ([\d.]+) [ ] CPU }xms);
330 # Tell the user what we discovered.
331 say {*STDOUT} "Performing $iterations iterations takes $time seconds"
332 or die "$0: cannot write to standard output: $!\n";
334 # If this is what we're looking for, we're done.
335 if (abs($time - $target) < $delta) {
339 # Determine the new iteration target.
340 if ($time > $target) {
345 if ($time < $target && $high == 0) {
346 $iterations = $iterations * 2;
348 $iterations = int(($high + $low) / 2);
352 # Report the result and return it.
353 say {*STDOUT} "Use $iterations iterations"
354 or die "$0: cannot write to standard output: $!\n";
358 ##############################################################################
360 ##############################################################################
362 # Given a principal and a password, determine whether the password was found
363 # in the password history for that user.
365 # $path - Path to the history file
366 # $principal - Principal for which to check history
367 # $password - Check history for this password
369 # Returns: True if $password is found in history, false otherwise
370 # Throws: On failure to open, lock, or tie the database
372 my ($path, $principal, $password) = @_;
374 # Open and lock the database and retrieve the history for the user.
375 # We have to lock for write so that we can create the database if it
376 # doesn't already exist. Password change should be infrequent enough
377 # and our window is fast enough that it shouldn't matter. We do this
378 # in a separate scope so that the history hash goes out of scope and
379 # is freed and unlocked.
383 my $mode = O_CREAT | O_RDWR;
384 tie(%history, 'DB_File::Lock', [$path, $mode, oct(600)], 'write')
385 or die "$0: cannot open $path: $!\n";
386 $history_json = $history{$principal};
389 # If there is no history for the user, return the trivial false.
390 if (!defined($history_json)) {
394 # Decode history from JSON. If this fails (corrupt history), treat it as
395 # if the user has no history, but log the error message.
396 my $history_ref = eval { decode_json($history_json) };
397 if (!defined($history_ref)) {
398 log_error($principal, "history JSON decoding failed: $@");
402 # Finally, check the password against the hashes in history.
403 return is_in_history($principal, $password, $history_ref);
406 # Write a new history entry to the database given the principal and the
407 # password to record. History records are stored as JSON arrays of objects,
408 # with keys "timestamp" and "hash".
410 # $path - Path to the history file
411 # $principal - Principal for which to check history
412 # $password - Check history for this password
415 # Throws: On failure to open, lock, or tie the database
417 my ($path, $principal, $password) = @_;
419 # Open and lock the database for write.
421 my $mode = O_CREAT | O_RDWR;
422 tie(%history, 'DB_File::Lock', [$path, $mode, oct(600)], 'write')
423 or die "$0: cannot open $path: $!\n";
425 # Read the existing history. If the existing history is corrupt, treat
426 # that as equivalent to not having any history, but log an error.
427 my $history_json = $history{$principal};
429 if (defined($history_json)) {
430 $history_ref = eval { decode_json($history_json) };
432 log_error($principal, "history JSON decoding failed: $@");
435 if (!defined($history_ref)) {
439 # Add a new history entry.
440 my $entry = { timestamp => time(), hash => password_hash($password) };
441 unshift(@{$history_ref}, $entry);
443 # Store the encoded data back in the history database.
444 $history{$principal} = encode_json($history_ref);
446 # The database is closed and unlocked when %history goes out of scope.
447 # Unfortunately, we lose on error detection here, since there doesn't
448 # appear to be a way to determine whether all the writes succeeded. But
449 # losing a bit of history in the rare error case of failing to write to
450 # local disk is probably not a big deal.
454 # Write statistics about password length. Given the length of the password
455 # and the path to the length statistics database, increments the counter for
456 # that password length.
458 # Any failure to open or write to the database is ignored, since this is
459 # considered optional logging and should not block the password change.
461 # $path - Path to the length statistics file
462 # $length - Length of the accepted password
465 sub update_length_counts {
466 my ($path, $length) = @_;
468 # Open and lock the database for write.
470 my $mode = O_CREAT | O_RDWR;
471 tie(%lengths, 'DB_File::Lock', [$path, $mode, oct(600)], 'write')
474 # Write each of the hashes.
477 # The database is closed and unlocked when %lengths goes out of scope.
481 ##############################################################################
482 # Heimdal password quality protocol
483 ##############################################################################
485 # Run another external password quality checker and return the results. This
486 # allows us to chain to another program that handles the actual strength
487 # checking prior to handling history.
489 # $principal - Principal attempting to change their password
490 # $password - The new password
492 # Returns: Scalar context: true if the password was accepted, false otherwise
493 # List context: whether the password is okay, the exit status of the
494 # quality checking program, and the error message if the first
496 # Throws: Text exception on failure to execute the program, or read or write
497 # from it or to it, or if it fails without an error
499 my ($principal, $password) = @_;
501 # Run the external quality checking program. If we're root, we'll run it
502 # as the strength checking user and group.
503 my $in = "principal: $principal\nnew-password: $password\nend\n";
504 my $init = sub { drop_privileges($STRENGTH_USER, $STRENGTH_GROUP) };
506 run([$STRENGTH_PROGRAM, $principal], \$in, \$out, \$err, init => $init);
507 my $status = ($? >> 8);
510 my $okay = ($status == 0 && $out eq "APPROVED\n");
512 # If the program failed, collect the error message.
515 $err =~ s{ \n .* }{}xms;
517 die "$0: password strength checking failed without an error\n";
521 # Return the results.
522 return wantarray ? ($okay, $err, $status) : $okay;
525 # Read a Heimdal external password quality checking request from the provided
526 # file handle and return the principal (ignored for our application) and the
529 # The protocol expects the following data (without leading whitespace) on
530 # standard input, in precisely this order:
532 # principal: <principal>
533 # new-password: <password>
536 # There is one and only one space after the colon, and any subsequent spaces
537 # are part of the value (such as leading spaces in the password).
539 # $fh - File handle from which to read
541 # Returns: Scalar context: the password
542 # List context: a list of the password and the principal
543 # Throws: Text exception on any protocol violations or IO errors
544 sub read_change_data {
546 my @keys = qw(principal new-password);
549 # Read the data elements we expect. Verify that they come in the correct
550 # order and the correct format.
552 for my $key (@keys) {
553 my $line = readline($fh);
554 if (!defined($line)) {
555 die "$0: truncated input before $key: $!\n";
558 if ($line =~ s{ \A \Q$key\E : [ ] }{}xms) {
561 die "$0: unrecognized input line before $key\n";
565 # The final line of input must be a literal "end\n";
566 my $line = readline($fh);
567 if (!defined($line)) {
568 die "$0: truncated input before end: $!\n";
569 } elsif ($line ne "end\n") {
570 die "$0: unrecognized input line before end\n";
573 # Return the results.
574 my $password = $data{'new-password'};
575 my $principal = $data{principal};
576 return wantarray ? ($password, $principal) : $password;
579 ##############################################################################
581 ##############################################################################
583 # Always flush output.
586 # Clean up the script name for error reporting.
588 local $0 = basename($0);
590 # Parse the argument list.
591 my ($opt, $usage) = describe_options(
593 ['benchmark|b=f', 'Benchmark hash iterations for this target time'],
594 ['database|d=s', 'Path to the history database, overriding the default'],
595 ['help|h', 'Print usage message and exit'],
596 ['manual|man|m', 'Print full manual and exit'],
597 ['quiet|q', 'Suppress logging to syslog'],
598 ['stats|S=s', 'Path to hash of length statistics'],
599 ['strength|s=s', 'Path to strength checking program to run'],
602 print {*STDOUT} $usage->text
603 or die "$0: cannot write to standard output: $!\n";
605 } elsif ($opt->manual) {
606 say {*STDOUT} 'Feeding myself to perldoc, please wait...'
607 or die "$0: cannot write to standard output: $!\n";
608 exec('perldoc', '-t', $fullpath);
610 my $database = $opt->database || $HISTORY_PATH;
611 my $stats_db = $opt->stats || $LENGTH_STATS_PATH;
613 # If asked to do benchmarking, ignore other arguments and just do that.
614 # Currently, we hard-code a 0.005-second granularity on our binary search.
615 if ($opt->benchmark) {
616 find_iteration_count($opt->benchmark, 0.005);
620 # Open syslog for result reporting.
624 openlog($0, 'pid', LOG_AUTH);
627 # Read the principal and password that we're supposed to check.
628 my ($password, $principal) = read_change_data(\*STDIN);
630 # Delegate to the external strength checking program.
631 my ($okay, $error, $status) = strength_check($principal, $password);
633 log_result($principal, 'rejected', $error);
638 # Drop privileges for the rest of the program.
639 drop_privileges($HISTORY_USER, $HISTORY_GROUP);
641 # Hash the password and check history. Exit if a hash is in history.
642 if (check_history($database, $principal, $password)) {
643 log_result($principal, 'rejected', $REJECT_MESSAGE);
644 warn "$REJECT_MESSAGE\n";
648 # The password is accepted. Record it, update the length counter, and return
650 log_result($principal, 'accepted');
651 write_history($database, $principal, $password);
652 say {*STDOUT} 'APPROVED'
653 or die "$0: cannot write to standard output: $!\n";
654 update_length_counts($stats_db, length($password));
659 ##############################################################################
661 ##############################################################################
664 heimdal-history heimdal-strength Heimdal -hm BerkeleyDB timestamps POSIX
665 whitespace API Allbery sublicense MERCHANTABILITY NONINFRINGEMENT syslog
666 pseudorandom JSON LDAP-compatible PBKDF2 SHA-256
670 heimdal-history - Password history via Heimdal external strength checking
674 B<heimdal-history> [B<-hmq>] [B<-b> I<target-time>] [B<-d> I<database>]
675 [B<-S> I<length-stats-db>] [B<-s> I<strength-program>] [B<principal>]
679 B<heimdal-history> is an implementation of password history via the
680 Heimdal external password strength checking interface. It stores separate
681 history for each principal, hashed using Crypt::PBKDF2 with
682 randomly-generated salt. (The randomness is from a weak pseudorandom
683 number generator, not strongly random.)
685 Password history is stored in a BerkeleyDB DB_HASH file. The key is the
686 principal. The value is a JSON array of objects, each of which has two
687 keys. C<timestamp> contains the time when the history entry was added (in
688 POSIX seconds since UNIX epoch), and C<hash> contains the hash of a
689 previously-used password in the Crypt::PBKDF2 LDAP-compatible format.
690 Passwords are hashed using PBKDF2 (from PKCS#5) with SHA-256 as the
691 underlying hash function using a number of rounds configured in this
692 script. See L<Crypt::PBKDF2> for more information.
694 B<heimdal-history> also checks password strength before checking history.
695 It does so by invoking another program that also uses the Heimdal external
696 password strength checking interface. By default, it runs
697 B</usr/bin/heimdal-strength>. Only if that program approves the password
698 does it hash it and check history.
700 As with any implementation of the Heimdal external password strength
701 checking protocol, B<heimdal-history> expects, on standard input:
703 principal: <principal>
704 new-password: <password>
707 (with no leading whitespace). <principal> is the principal changing its
708 password (passed to the other password strength checking program but
709 otherwise unused here), and <password> is the new password. There must
710 be exactly one space after the colon. Any subsequent spaces are taken to
711 be part of the principal or password.
713 If invoked as root, B<heimdal-history> will run the external strength
714 checking program as user C<nobody> and group C<nogroup>, and will check
715 and write to the history database as user C<_history> and group
716 C<_history>. These users must exist on the system if it is run as root.
718 The result of each password check will be logged to syslog (priority
719 LOG_INFO, facility LOG_AUTH). Each log line will be a set of key/value
720 pairs in the format C<< I<key>=I<value> >>. The keys are:
726 The action performed (currently always C<check>).
730 The principal for which a password was checked.
734 An internal error message that did not stop the history check, but which
735 may indicate that something is wrong with the history database (such as
736 corrupted entries or invalid hashes). If this key is present, neither
737 C<result> nor C<reason> will be present. There will be a subsequent log
738 message from the same invocation giving the final result of the history
739 check (assuming B<heimdal-history> doesn't exit with a fatal error).
743 Either C<accepted> or C<rejected>.
747 If the password was rejected, the reason for the rejection.
751 The value will be surrounded with double quotes if it contains a double
752 quote or space. Any double quotes in the value will be doubled, so C<">
759 =item B<-b> I<target-time>, B<--benchmark>=I<target-time>
761 Do not do a password history check. Instead, benchmark the hash algorithm
762 with various possible iteration counts and find an iteration count that
763 results in I<target-time> seconds of computation time required to hash a
764 password (which should be a real number). A result will be considered
765 acceptable if it is within 0.005 seconds of the target time. The results
766 will be printed to standard output and then B<heimdal-history> will exit
769 =item B<-d> I<database>, B<--database>=I<database>
771 Use I<database> as the history database file instead of the default
772 (F</var/lib/heimdal-history/history.db>). Primarily used for testing,
773 since Heimdal won't pass this argument.
775 =item B<-h>, B<--help>
777 Print a short usage message and exit.
779 =item B<-m>, B<--manual>, B<--man>
781 Display this manual and exit.
783 =item B<-q>, B<--quiet>
785 Suppress logging to syslog and only return the results on standard output
786 and standard error. Primarily used for testing, since Heimdal won't pass
789 =item B<-S> I<length-stats-db>, B<--stats>=I<length-stats-db>
791 Use I<length-stats-db> as the database file for password length statistics
792 instead of the default (F</var/lib/heimdal-history/lengths.db>).
793 Primarily used for testing, since Heimdal won't pass this argument.
795 =item B<-s> I<strength-program>, B<--strength>=I<strength-program>
797 Run I<strength-program> as the external strength-checking program instead
798 of the default (F</usr/bin/heimdal-strength>). Primarily used for
799 testing, since Heimdal won't pass this argument.
805 On approval of the password, B<heimdal-history> will print C<APPROVED> and
806 a newline to standard output and exit with status 0.
808 If the password is rejected by the strength checking program or if it (or
809 a version with a single character removed) matches one of the hashes stored
810 in the password history, B<heimdal-history> will print the reason for
811 rejection to standard error and exit with status 0.
813 On any internal error, B<heimdal-history> will print the error to standard
814 error and exit with a non-zero status.
820 =item F</usr/bin/heimdal-strength>
822 The default password strength checking program. This program must follow
823 the Heimdal external password strength checking API.
825 =item F</var/lib/heimdal-history/history.db>
827 The default database path. If B<heimdal-strength> is run as root, this
828 file needs to be readable and writable by user C<_history> and group
829 C<_history>. If it doesn't exist, it will be created with mode 0600.
831 =item F</var/lib/heimdal-history/history.db.lock>
833 The lock file used to synchronize access to the history database. As with
834 the history database, if B<heimdal-strength> is run as root, this file
835 needs to be readable and writable by user C<_history> and group
838 =item F</var/lib/heimdal-history/lengths.db>
840 The default length statistics path, which will be a BerkeleyDB DB_HASH
841 file of password lengths to counts of passwords with that length. If
842 B<heimdal-strength> is run as root, this file needs to be readable and
843 writable by user C<_history> and group C<_history>. If it doesn't exist,
844 it will be created with mode 0600.
846 =item F</var/lib/heimdal-history/lengths.db.lock>
848 The lock file used to synchronize access to the length statistics
849 database. As with the length statistics database, if B<heimdal-strength>
850 is run as root, this file needs to be readable and writable by user
851 C<_history> and group C<_history>.
857 Russ Allbery <eagle@eyrie.org>
859 =head1 COPYRIGHT AND LICENSE
861 Copyright 2013, 2014 The Board of Trustees of the Leland Stanford Junior
864 Permission is hereby granted, free of charge, to any person obtaining a
865 copy of this software and associated documentation files (the "Software"),
866 to deal in the Software without restriction, including without limitation
867 the rights to use, copy, modify, merge, publish, distribute, sublicense,
868 and/or sell copies of the Software, and to permit persons to whom the
869 Software is furnished to do so, subject to the following conditions:
871 The above copyright notice and this permission notice shall be included in
872 all copies or substantial portions of the Software.
874 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
875 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
876 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
877 THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
878 LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
879 FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
880 DEALINGS IN THE SOFTWARE.
884 L<Crypt::PBKDF2>, L<heimdal-strength(1)>