tests/tools/heimdal-strength-t

   1 #!/usr/bin/perl
   2 #
   3 # Test suite for basic Heimdal external strength checking functionality.
   4 #
   5 # Written by Russ Allbery <eagle@eyrie.org>
   6 # Copyright 2009, 2012, 2013
   7 #     The Board of Trustees of the Leland Stanford Junior University
   8 #
   9 # See LICENSE for licensing terms.
  10
  11 use 5.006;
  12 use strict;
  13 use warnings;
  14
  15 use lib "$ENV{SOURCE}/tap/perl";
  16
  17 use File::Copy qw(copy);
  18 use Test::RRA qw(use_prereq);
  19 use Test::RRA::Automake qw(test_file_path);
  20
  21 use_prereq('File::Slurp');
  22 use_prereq('IPC::Run', 'run');
  23 use_prereq('JSON');
  24 use_prereq('Test::More', '0.87_01');
  25
  26 # Run the newly-built heimdal-strength command and return the status, output,
  27 # and error output as a list.
  28 #
  29 # $principal - Principal to pass to the command
  30 # $password  - Password to pass to the command
  31 #
  32 # Returns: The exit status, standard output, and standard error as a list
  33 #  Throws: Text exception on failure to run the test program
  34 sub run_heimdal_strength {
  35     my ($principal, $password) = @_;
  36
  37     # Build the input to the strength checking program.
  38     my $in = "principal: $principal\n";
  39     $in .= "new-password: $password\n";
  40     $in .= "end\n";
  41
  42     # Find the newly-built password checking program.
  43     my $program = test_file_path('../tools/heimdal-strength');
  44
  45     # Run the password strength checker.
  46     my ($out, $err);
  47     run([$program, $principal], \$in, \$out, \$err);
  48     my $status = ($? >> 8);
  49
  50     # Return the results.
  51     return ($status, $out, $err);
  52 }
  53
  54 # Run the newly-built heimdal-strength command to check a password and reports
  55 # the results using Test::More.  This uses the standard protocol for Heimdal
  56 # external password strength checking programs.
  57 #
  58 # $test_ref - Reference to hash of test parameters
  59 #   name      - The name of the test case
  60 #   principal - The principal changing its password
  61 #   password  - The new password
  62 #   status    - If present, the exit status (otherwise, it should be 0)
  63 #   error     - If present, the expected rejection error
  64 #
  65 # Returns: undef
  66 #  Throws: Text exception on failure to run the test program
  67 sub check_password {
  68     my ($test_ref) = @_;
  69     my $principal  = $test_ref->{principal};
  70     my $password   = $test_ref->{password};
  71
  72     # Run the heimdal-strength command.
  73     my ($status, $out, $err) = run_heimdal_strength($principal, $password);
  74     chomp($out, $err);
  75
  76     # Check the results.  If there is an error in the password, it should come
  77     # on standard error; otherwise, standard output should be APPROVED.  If
  78     # there is a non-zero exit status, we expect the error on standard error
  79     # and use that field to check for system errors.
  80     is($status, $test_ref->{status} || 0, "$test_ref->{name} (status)");
  81     if (defined($test_ref->{error})) {
  82         is($err, $test_ref->{error}, '...error message');
  83         is($out, q{}, '...no output');
  84     } else {
  85         is($err, q{},        '...no errors');
  86         is($out, 'APPROVED', '...approved');
  87     }
  88     return;
  89 }
  90
  91 # Create a new krb5.conf file that includes arbitrary settings passed in via
  92 # a hash reference.
  93 #
  94 # $settings_ref - Hash of keys and values to put into [appdefaults]
  95 #
  96 # Returns: Path to the new krb5.conf file
  97 #  Throws: Text exception if the new krb5.conf file cannot be created
  98 sub create_krb5_conf {
  99     my ($settings_ref) = @_;
 100
 101     # Paths for krb5.conf creation.
 102     my $old    = test_file_path('data/krb5.conf');
 103     my $tmpdir = $ENV{BUILD} ? "$ENV{BUILD}/tmp" : 'tests/tmp';
 104     my $new    = "$tmpdir/krb5.conf";
 105
 106     # Create a temporary directory for the new file.
 107     if (!-d $tmpdir) {
 108         mkdir($tmpdir, 0777) or die "Cannot create $tmpdir: $!\n";
 109     }
 110
 111     # Start with the testing krb5.conf file shipped in the package.
 112     copy($old, $new) or die "Cannot copy $old to $new: $!\n";
 113
 114     # Append the local configuration.
 115     open(my $config, '>>', $new) or die "Cannot append to $new: $!\n";
 116     print {$config} "\n[appdefaults]\n    krb5-strength = {\n"
 117       or die "Cannot append to $new: $!\n";
 118     for my $key (keys %{$settings_ref}) {
 119         print {$config} q{ } x 8, $key, ' = ', $settings_ref->{$key}, "\n"
 120           or die "Cannot append to $new: $!\n";
 121     }
 122     print {$config} "    }\n"
 123       or die "Cannot append to $new: $!\n";
 124     close($config) or die "Cannot append to $new: $!\n";
 125
 126     # Return the path to the new file.
 127     return $new;
 128 }
 129
 130 # Load a set of password test cases and return them as a list.  The given file
 131 # name is relative to data/passwords in the test suite.
 132 #
 133 # $file - The file name containing the test data in JSON
 134 #
 135 # Returns: List of anonymous hashes representing password test cases
 136 #  Throws: Text exception on failure to load the test data
 137 sub load_password_tests {
 138     my ($file) = @_;
 139     my $path = test_file_path("data/passwords/$file");
 140
 141     # Load the test file data into memory.
 142     my $testdata = read_file($path);
 143
 144     # Decode the JSON into Perl objects and return them.
 145     my $json = JSON->new->utf8;
 146     return $json->decode($testdata);
 147 }
 148
 149 # Load the password tests from JSON.  Accumulate a total count of tests for
 150 # the testing plan.
 151 my (%tests, $count);
 152 for my $type (qw(cdb classes cracklib length letter principal)) {
 153     my $tests = load_password_tests("$type.json");
 154     $tests{$type} = $tests;
 155     $count += scalar(@{$tests});
 156 }
 157
 158 # We run the principal tests twice, once for CrackLib and once for CDB.
 159 $count += scalar(@{ $tests{principal} });
 160
 161 # We can now calculate our plan based on three tests for each password test.
 162 plan(tests => $count * 3);
 163
 164 # Install the krb5.conf file with a configuration pointing to the test
 165 # CrackLib dictionary.
 166 my $datadir = $ENV{BUILD} ? "$ENV{BUILD}/data" : 'tests/data';
 167 my $krb5_conf
 168   = create_krb5_conf({ password_dictionary => "$datadir/dictionary" });
 169 local $ENV{KRB5_CONFIG} = $krb5_conf;
 170
 171 # Run the CrackLib password tests and based-on-principal tests from JSON.
 172 note('CrackLib tests');
 173 for my $test (@{ $tests{cracklib} }) {
 174     check_password($test);
 175 }
 176 note('Generic tests with CrackLib');
 177 for my $test (@{ $tests{principal} }) {
 178     check_password($test);
 179 }
 180
 181 # Install the krb5.conf file with a length restriction.
 182 $krb5_conf = create_krb5_conf({ minimum_length => 12 });
 183 local $ENV{KRB5_CONFIG} = $krb5_conf;
 184
 185 # Run the password length checks.
 186 note('Password length checks');
 187 for my $test (@{ $tests{length} }) {
 188     check_password($test);
 189 }
 190
 191 # Install the krb5.conf file for simple character class restrictions.
 192 $krb5_conf = create_krb5_conf(
 193     {
 194         require_ascii_printable => 'true',
 195         require_non_letter      => 'true',
 196     }
 197 );
 198 local $ENV{KRB5_CONFIG} = $krb5_conf;
 199
 200 # Run the simple character class tests.
 201 note('Simple password character class checks');
 202 for my $test (@{ $tests{letter} }) {
 203     check_password($test);
 204 }
 205
 206 # Install the krb5.conf file for complex character class restrictions.
 207 my $classes = '8-19:lower,upper 8-15:digit 8-11:symbol';
 208 $krb5_conf = create_krb5_conf({ require_classes => $classes });
 209 local $ENV{KRB5_CONFIG} = $krb5_conf;
 210
 211 # Run the complex character class tests.
 212 note('Complex password character class checks');
 213 for my $test (@{ $tests{classes} }) {
 214     check_password($test);
 215 }
 216
 217 # Install the krb5.conf file with configuration pointing to the CDB
 218 # dictionary.
 219 my $cdb_database = test_file_path('data/wordlist.cdb');
 220 $krb5_conf = create_krb5_conf({ password_dictionary_cdb => $cdb_database });
 221 local $ENV{KRB5_CONFIG} = $krb5_conf;
 222
 223 # Check whether we were built with CDB support.  If so, run those tests.
 224 my ($status, $output, $err) = run_heimdal_strength('test', 'password');
 225 SKIP: {
 226     if ($status == 1 && $err =~ m{ not [ ] built [ ] with [ ] CDB }xms) {
 227         my $total = scalar(@{ $tests{cdb} }) + scalar(@{ $tests{principal} });
 228         skip('not built with CDB support', $total * 3);
 229     }
 230
 231     # Run the CDB and principal password tests from JSON.
 232     note('CDB tests');
 233     for my $test (@{ $tests{cdb} }) {
 234         check_password($test);
 235     }
 236     note('Generic tests with CDB');
 237     for my $test (@{ $tests{principal} }) {
 238         check_password($test);
 239     }
 240 }
 241
 242 # Clean up our temporary krb5.conf file on any exit.
 243 END {
 244     my $tmpdir = $ENV{BUILD} ? "$ENV{BUILD}/tmp" : 'tests/tmp';
 245     my $config = "$tmpdir/krb5.conf";
 246     if (-f $config) {
 247         unlink($config) or warn "Cannot remove $config\n";
 248         rmdir($tmpdir);
 249     }
 250 }