tests/tap/perl/Test/RRA/Config.pm

   1 # Configuration for Perl test cases.
   2 #
   3 # In order to reuse the same Perl test cases in multiple packages, I use a
   4 # configuration file to store some package-specific data.  This module loads
   5 # that configuration and provides the namespace for the configuration
   6 # settings.
   7 #
   8 # SPDX-License-Identifier: MIT
   9
  10 package Test::RRA::Config;
  11
  12 use 5.010;
  13 use base qw(Exporter);
  14 use strict;
  15 use warnings;
  16
  17 use Test::More;
  18
  19 # Declare variables that should be set in BEGIN for robustness.
  20 our (@EXPORT_OK, $VERSION);
  21
  22 # Set $VERSION and everything export-related in a BEGIN block for robustness
  23 # against circular module loading (not that we load any modules, but
  24 # consistency is good).
  25 BEGIN {
  26     @EXPORT_OK = qw(
  27         $COVERAGE_LEVEL @COVERAGE_SKIP_TESTS @CRITIC_IGNORE $LIBRARY_PATH
  28         $MINIMUM_VERSION %MINIMUM_VERSION @MODULE_VERSION_IGNORE
  29         @POD_COVERAGE_EXCLUDE @STRICT_IGNORE @STRICT_PREREQ
  30     );
  31
  32     # This version should match the corresponding rra-c-util release, but with
  33     # two digits for the minor version, including a leading zero if necessary,
  34     # so that it will sort properly.
  35     $VERSION = '10.05';
  36 }
  37
  38 # If C_TAP_BUILD or C_TAP_SOURCE are set in the environment, look for
  39 # data/perl.conf under those paths for a C Automake package.  Otherwise, look
  40 # in t/data/perl.conf for a standalone Perl module or tests/data/perl.conf for
  41 # Perl tests embedded in a larger distribution.  Don't use Test::RRA::Automake
  42 # since it may not exist.
  43 our $PATH;
  44 for my $base ($ENV{C_TAP_BUILD}, $ENV{C_TAP_SOURCE}, './t', './tests') {
  45     next if !defined($base);
  46     my $path = "$base/data/perl.conf";
  47     if (-r $path) {
  48         $PATH = $path;
  49         last;
  50     }
  51 }
  52 if (!defined($PATH)) {
  53     BAIL_OUT('cannot find data/perl.conf');
  54 }
  55
  56 # Pre-declare all of our variables and set any defaults.
  57 our $COVERAGE_LEVEL = 100;
  58 our @COVERAGE_SKIP_TESTS;
  59 our @CRITIC_IGNORE;
  60 our $LIBRARY_PATH;
  61 our $MINIMUM_VERSION = '5.010';
  62 our %MINIMUM_VERSION;
  63 our @MODULE_VERSION_IGNORE;
  64 our @POD_COVERAGE_EXCLUDE;
  65 our @STRICT_IGNORE;
  66 our @STRICT_PREREQ;
  67
  68 # Load the configuration.
  69 if (!do($PATH)) {
  70     my $error = $@ || $! || 'loading file did not return true';
  71     BAIL_OUT("cannot load $PATH: $error");
  72 }
  73
  74 1;
  75 __END__
  76
  77 =for stopwords
  78 Allbery rra-c-util Automake perlcritic .libs namespace subdirectory sublicense
  79 MERCHANTABILITY NONINFRINGEMENT regexes
  80
  81 =head1 NAME
  82
  83 Test::RRA::Config - Perl test configuration
  84
  85 =head1 SYNOPSIS
  86
  87     use Test::RRA::Config qw($MINIMUM_VERSION);
  88     print "Required Perl version is $MINIMUM_VERSION\n";
  89
  90 =head1 DESCRIPTION
  91
  92 Test::RRA::Config encapsulates per-package configuration for generic Perl test
  93 programs that are shared between multiple packages using the rra-c-util
  94 infrastructure.  It handles locating and loading the test configuration file
  95 for both C Automake packages and stand-alone Perl modules.
  96
  97 Test::RRA::Config looks for a file named F<data/perl.conf> relative to the
  98 root of the test directory.  That root is taken from the environment variables
  99 C_TAP_BUILD or C_TAP_SOURCE (in that order) if set, which will be the case for
 100 C Automake packages using C TAP Harness.  If neither is set, it expects the
 101 root of the test directory to be a directory named F<t> relative to the
 102 current directory, which will be the case for stand-alone Perl modules.
 103
 104 The following variables are supported:
 105
 106 =over 4
 107
 108 =item $COVERAGE_LEVEL
 109
 110 The coverage level achieved by the test suite for Perl test coverage testing
 111 using Test::Strict, as a percentage.  The test will fail if test coverage less
 112 than this percentage is achieved.  If not given, defaults to 100.
 113
 114 =item @COVERAGE_SKIP_TESTS
 115
 116 Directories under F<t> whose tests should be skipped when doing coverage
 117 testing.  This can be tests that won't contribute to coverage or tests that
 118 don't run properly under Devel::Cover for some reason (such as ones that use
 119 taint checking).  F<docs> and F<style> will always be skipped regardless of
 120 this setting.
 121
 122 =item @CRITIC_IGNORE
 123
 124 Additional files or directories to ignore when doing recursive perlcritic
 125 testing.  To ignore files that will be installed, the path should start with
 126 F<blib>.
 127
 128 =item $LIBRARY_PATH
 129
 130 Add this directory (or a F<.libs> subdirectory) relative to the top of the
 131 source tree to LD_LIBRARY_PATH when checking the syntax of Perl modules.  This
 132 may be required to pick up libraries that are used by in-tree Perl modules so
 133 that Perl scripts can pass a syntax check.
 134
 135 =item $MINIMUM_VERSION
 136
 137 Default minimum version requirement for included Perl scripts.  If not given,
 138 defaults to 5.010.
 139
 140 =item %MINIMUM_VERSION
 141
 142 Minimum version exceptions for specific directories.  The keys should be
 143 minimum versions of Perl to enforce.  The value for each key should be a
 144 reference to an array of either top-level directory names or directory names
 145 starting with F<tests/>.  All files in those directories will have that
 146 minimum Perl version constraint imposed instead of $MINIMUM_VERSION.
 147
 148 =item @MODULE_VERSION_IGNORE
 149
 150 File names to ignore when checking that all modules in a distribution have the
 151 same version.  Sometimes, some specific modules need separate, special version
 152 handling, such as modules defining database schemata for DBIx::Class, and
 153 can't follow the version of the larger package.
 154
 155 =item @POD_COVERAGE_EXCLUDE
 156
 157 Regexes that match method names that should be excluded from POD coverage
 158 testing.  Normally, all methods have to be documented in the POD for a Perl
 159 module, but methods matching any of these regexes will be considered private
 160 and won't require documentation.
 161
 162 =item @STRICT_IGNORE
 163
 164 Additional directories to ignore when doing recursive Test::Strict testing for
 165 C<use strict> and C<use warnings>.  The contents of this directory must be
 166 either top-level directory names or directory names starting with F<tests/>.
 167
 168 =item @STRICT_PREREQ
 169
 170 A list of Perl modules that have to be available in order to do meaningful
 171 Test::Strict testing.  If any of the modules cannot be loaded via C<use>,
 172 Test::Strict checking will be skipped.  There is currently no way to require
 173 specific versions of the modules.
 174
 175 =back
 176
 177 No variables are exported by default, but the variables can be imported into
 178 the local namespace to avoid long variable names.
 179
 180 =head1 AUTHOR
 181
 182 Russ Allbery <eagle@eyrie.org>
 183
 184 =head1 COPYRIGHT AND LICENSE
 185
 186 Copyright 2015-2016, 2019, 2021 Russ Allbery <eagle@eyrie.org>
 187
 188 Copyright 2013-2014 The Board of Trustees of the Leland Stanford Junior
 189 University
 190
 191 Permission is hereby granted, free of charge, to any person obtaining a copy
 192 of this software and associated documentation files (the "Software"), to deal
 193 in the Software without restriction, including without limitation the rights
 194 to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 195 copies of the Software, and to permit persons to whom the Software is
 196 furnished to do so, subject to the following conditions:
 197
 198 The above copyright notice and this permission notice shall be included in all
 199 copies or substantial portions of the Software.
 200
 201 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 202 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 203 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL THE
 204 AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 205 LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 206 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 207 SOFTWARE.
 208
 209 =head1 SEE ALSO
 210
 211 perlcritic(1), Test::MinimumVersion(3), Test::RRA(3), Test::RRA::Automake(3),
 212 Test::Strict(3)
 213
 214 This module is maintained in the rra-c-util package.  The current version is
 215 available from L<https://www.eyrie.org/~eagle/software/rra-c-util/>.
 216
 217 The C TAP Harness test driver and libraries for TAP-based C testing are
 218 available from L<https://www.eyrie.org/~eagle/software/c-tap-harness/>.
 219
 220 =cut
 221
 222 # Local Variables:
 223 # copyright-at-end-flag: t
 224 # End: