configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Written by Russ Allbery <rra@stanford.edu>
   4 dnl Copyright 2006, 2007, 2009, 2010, 2012, 2013
   5 dnl     The Board of Trustees of the Leland Stanford Junior University
   6 dnl
   7 dnl See LICENSE for licensing terms.
   8
   9 dnl Basic Autoconf configuration.
  10 AC_PREREQ([2.64])
  11 AC_INIT([krb5-strength], [1.1], [rra@stanford.edu])
  12 AC_CONFIG_AUX_DIR([build-aux])
  13 AC_CONFIG_LIBOBJ_DIR([portable])
  14 AC_CONFIG_MACRO_DIR([m4])
  15 AM_INIT_AUTOMAKE([1.11 check-news dist-xz foreign silent-rules subdir-objects
  16     -Wall -Werror])
  17 AM_MAINTAINER_MODE
  18
  19 dnl Probe for basic build system tools.
  20 AC_PROG_CC
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AM_PROG_CC_C_O
  24 AC_PROG_INSTALL
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26 AM_DISABLE_STATIC
  27 AC_PROG_LIBTOOL
  28
  29 dnl External libraries.
  30 RRA_LIB_CRACKLIB
  31 RRA_LIB_KRB5
  32 RRA_LIB_KRB5_SWITCH
  33 AC_CHECK_HEADERS([kadm5/kadm5-pwcheck.h kadm5/kadm5_err.h], [], [],
  34     [RRA_INCLUDE_KRB5])
  35 AC_CHECK_HEADERS([krb5/pwqual_plugin.h], [], [], [RRA_INCLUDES_KRB5])
  36 AC_CHECK_TYPES([krb5_realm], [], [], [RRA_INCLUDES_KRB5])
  37 AC_CHECK_FUNCS([krb5_free_default_realm \
  38     krb5_free_string \
  39     krb5_principal_get_realm \
  40     krb5_get_init_creds_opt_alloc \
  41     krb5_get_init_creds_opt_set_default_flags \
  42     krb5_xfree])
  43 AC_CHECK_FUNCS([krb5_get_init_creds_opt_free],
  44     [RRA_FUNC_KRB5_GET_INIT_CREDS_OPT_FREE_ARGS])
  45 AC_CHECK_DECLS([krb5_kt_free_entry], [], [], [RRA_INCLUDES_KRB5])
  46 AC_LIBOBJ([krb5-extra])
  47 RRA_LIB_KRB5_RESTORE
  48
  49 dnl Probe for libdl, which is used for the test suite.
  50 save_LIBS="$LIBS"
  51 AC_SEARCH_LIBS([dlopen], [dl], [DL_LIBS="$LIBS"])
  52 LIBS="$save_LIBS"
  53 AC_SUBST([DL_LIBS])
  54
  55 dnl Checks for basic C functionality.
  56 AC_HEADER_STDBOOL
  57 AC_CHECK_HEADERS([sys/bittypes.h syslog.h])
  58 AC_CHECK_DECLS([snprintf, vsnprintf])
  59 RRA_C_C99_VAMACROS
  60 RRA_C_GNU_VAMACROS
  61 AC_TYPE_LONG_LONG_INT
  62 AC_TYPE_UINT8_T
  63 AC_TYPE_UINT16_T
  64 AC_TYPE_UINT32_T
  65 AC_CHECK_TYPES([ssize_t], [], [],
  66     [#include <sys/types.h>])
  67 RRA_FUNC_SNPRINTF
  68 AC_REPLACE_FUNCS([asprintf strlcat strlcpy])
  69
  70 dnl Write out the results.
  71 AC_CONFIG_FILES([Makefile])
  72 AC_CONFIG_HEADER([config.h])
  73 AC_OUTPUT