configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Written by Russ Allbery <rra@stanford.edu>
   4 dnl Copyright 2006, 2007, 2009, 2010, 2012
   5 dnl     The Board of Trustees of the Leland Stanford Junior University
   6 dnl
   7 dnl See LICENSE for licensing terms.
   8
   9 AC_PREREQ([2.64])
  10 AC_INIT([krb5-strength], [1.1], [rra@stanford.edu])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12 AC_CONFIG_LIBOBJ_DIR([portable])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AM_INIT_AUTOMAKE([1.11 check-news foreign silent-rules subdir-objects \
  15     -Wall -Werror])
  16 AM_MAINTAINER_MODE
  17
  18 AC_PROG_CC
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AM_PROG_CC_C_O
  21 AC_PROG_INSTALL
  22 AM_DISABLE_STATIC
  23 AC_PROG_LIBTOOL
  24
  25 AC_HEADER_STDBOOL
  26 AC_CHECK_HEADERS([sys/bittypes.h])
  27 AC_CHECK_DECLS([snprintf, vsnprintf])
  28 AC_TYPE_LONG_LONG_INT
  29 AC_CHECK_TYPES([ssize_t], [], [],
  30     [#include <sys/types.h>])
  31 AC_TYPE_UINT8_T
  32 AC_TYPE_UINT16_T
  33 AC_TYPE_UINT32_T
  34 RRA_FUNC_SNPRINTF
  35 AC_REPLACE_FUNCS([asprintf strlcat strlcpy])
  36
  37 save_LIBS="$LIBS"
  38 AC_SEARCH_LIBS([dlopen], [dl], [DL_LIBS="$LIBS"])
  39 LIBS="$save_LIBS"
  40 AC_SUBST([DL_LIBS])
  41
  42 RRA_LIB_CRACKLIB
  43 RRA_LIB_KRB5
  44 RRA_LIB_KRB5_SWITCH
  45 AC_CHECK_HEADERS([kadm5-pwcheck.h krb5/pwcheck_plugin.h])
  46 AC_CHECK_TYPES([krb5_realm], [], [], [RRA_INCLUDES_KRB5])
  47 RRA_LIB_KRB5_RESTORE
  48
  49 dnl Create the tests/data directory for builds outside the source directory.
  50 AC_CONFIG_COMMANDS([tests/data/.placeholder], [touch tests/data/.placeholder])
  51
  52 AC_CONFIG_FILES([Makefile])
  53 AC_CONFIG_HEADER([config.h])
  54 AC_OUTPUT