configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Written by Russ Allbery <eagle@eyrie.org>
   4 dnl Copyright 2006, 2007, 2009, 2010, 2012, 2013, 2014
   5 dnl     The Board of Trustees of the Leland Stanford Junior University
   6 dnl
   7 dnl See LICENSE for licensing terms.
   8
   9 dnl Basic Autoconf configuration.
  10 AC_PREREQ([2.64])
  11 AC_INIT([krb5-strength], [3.0], [eagle@eyrie.org])
  12 AC_CONFIG_AUX_DIR([build-aux])
  13 AC_CONFIG_LIBOBJ_DIR([portable])
  14 AC_CONFIG_MACRO_DIR([m4])
  15 AM_INIT_AUTOMAKE([1.11 check-news dist-xz foreign silent-rules subdir-objects
  16     -Wall -Werror])
  17 AM_MAINTAINER_MODE
  18
  19 dnl Probe for basic build system tools.
  20 AC_PROG_CC
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AM_PROG_CC_C_O
  24 AC_PROG_INSTALL
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26 AM_DISABLE_STATIC
  27 LT_INIT
  28
  29 dnl External libraries.
  30 RRA_LIB_CDB_OPTIONAL
  31 RRA_LIB_CRACKLIB
  32 AS_IF([test x"$rra_system_cracklib" = xyes],
  33     [RRA_LIB_CRACKLIB_SWITCH
  34      AC_CHECK_HEADERS([crack.h])
  35      RRA_LIB_CRACKLIB_RESTORE])
  36 RRA_LIB_KRB5
  37 RRA_LIB_KRB5_SWITCH
  38 AC_CHECK_HEADERS([kadm5/kadm5-pwcheck.h kadm5/kadm5_err.h], [], [],
  39     [RRA_INCLUDES_KRB5])
  40 AC_CHECK_HEADERS([krb5/pwqual_plugin.h], [], [], [RRA_INCLUDES_KRB5])
  41 AC_CHECK_TYPES([krb5_realm], [], [], [RRA_INCLUDES_KRB5])
  42 AC_CHECK_FUNCS([krb5_free_default_realm \
  43     krb5_free_string \
  44     krb5_get_init_creds_opt_alloc \
  45     krb5_get_init_creds_opt_set_default_flags \
  46     krb5_principal_get_realm \
  47     krb5_xfree])
  48 AC_CHECK_FUNCS([krb5_get_init_creds_opt_free],
  49     [RRA_FUNC_KRB5_GET_INIT_CREDS_OPT_FREE_ARGS])
  50 AC_CHECK_DECLS([krb5_kt_free_entry], [], [], [RRA_INCLUDES_KRB5])
  51 AC_LIBOBJ([krb5-extra])
  52 RRA_LIB_KRB5_RESTORE
  53 RRA_LIB_SQLITE_OPTIONAL
  54
  55 dnl Probe for libdl, which is used for the test suite.
  56 save_LIBS="$LIBS"
  57 AC_SEARCH_LIBS([dlopen], [dl], [DL_LIBS="$LIBS"])
  58 LIBS="$save_LIBS"
  59 AC_SUBST([DL_LIBS])
  60
  61 dnl Checks for basic C functionality.
  62 AC_HEADER_STDBOOL
  63 AC_CHECK_HEADERS([sys/bittypes.h sys/select.h syslog.h])
  64 AC_CHECK_DECLS([snprintf, vsnprintf])
  65 RRA_C_C99_VAMACROS
  66 RRA_C_GNU_VAMACROS
  67 AC_TYPE_LONG_LONG_INT
  68 AC_TYPE_UINT8_T
  69 AC_TYPE_UINT16_T
  70 AC_TYPE_UINT32_T
  71 AC_CHECK_TYPES([ssize_t], [], [],
  72     [#include <sys/types.h>])
  73 RRA_FUNC_SNPRINTF
  74 AC_CHECK_FUNCS([setrlimit])
  75 AC_REPLACE_FUNCS([asprintf mkstemp strndup])
  76
  77 dnl Write out the results.
  78 AC_CONFIG_FILES([Makefile])
  79 AC_CONFIG_HEADER([config.h])
  80 AC_OUTPUT